mirror of
https://github.com/holub/mame
synced 2025-05-08 23:31:54 +03:00
0837e7451a
* Sync with bgfx upstream revision b91d0b6 * Sync with bx upstream revision d60912b * Sync with bimg upstream revision bd81f60 * Add astc-codec decoder * Rename VertexDecl to VertexLayout * Rename UniformType enum Int1 to Sampler. * Add NVN stub * Fix unused-const-variable error on macOS * Drop redundant explicit language parameters buildoptions_cpp are only applied to c++ files and buildoptions_objcpp are only applied to objective c++ files. As such, hardcoding -x offers no benefit while preventing overrides (such as one needed by 3rdparty/bgfx/src/renderer_vk.cpp on macOS) from working. * Re-introduce -x c++ in places where C code is compiled as C++ to prevent clang from throwing a warning * Build bgfx as Objective-C++ on macOS It is needed due to included headers * Enable Direct3D12 and Vulkan bgfx rendering backends * Enable building of spirv shaders * Properly escape /c in cmd call * Comment out dx12 bgfx renderer * Honor VERBOSE setting during shaders build * Only invert hlsl shader XYZ_TO_sRGB matrix for opengl * Add spirv shaders * OpenGL ES needs transposed matrix too * Metal needs transposed matrix as well
136 lines
3.2 KiB
Plaintext
136 lines
3.2 KiB
Plaintext
/*
|
|
* Copyright 2019-2019 Attila Kocsis. All rights reserved.
|
|
* License: https://github.com/bkaradzic/bgfx#license-bsd-2-clause
|
|
*/
|
|
|
|
#include "entry_p.h"
|
|
#if BX_PLATFORM_OSX
|
|
|
|
#include <bx/allocator.h>
|
|
#include <bx/filepath.h>
|
|
#include <bx/string.h>
|
|
#include <bx/readerwriter.h>
|
|
#include <bx/process.h>
|
|
#include <bx/semaphore.h>
|
|
|
|
#import <AppKit/AppKit.h>
|
|
|
|
#include "dialog.h"
|
|
|
|
class Split
|
|
{
|
|
public:
|
|
Split(const bx::StringView& _str, char _ch)
|
|
: m_str(_str)
|
|
, m_token(_str.getPtr(), bx::strFind(_str, _ch).getPtr() )
|
|
, m_ch(_ch)
|
|
{
|
|
}
|
|
|
|
bx::StringView next()
|
|
{
|
|
bx::StringView result = m_token;
|
|
m_token = bx::strTrim(
|
|
bx::StringView(m_token.getTerm()+1
|
|
, bx::strFind(bx::StringView(m_token.getTerm()+1, m_str.getTerm() ), m_ch).getPtr() )
|
|
, " \t\n"
|
|
);
|
|
return result;
|
|
}
|
|
|
|
bool isDone() const
|
|
{
|
|
return m_token.isEmpty();
|
|
}
|
|
|
|
private:
|
|
const bx::StringView& m_str;
|
|
bx::StringView m_token;
|
|
char m_ch;
|
|
};
|
|
|
|
|
|
bool openFileSelectionDialog(
|
|
bx::FilePath& _inOutFilePath
|
|
, FileSelectionDialogType::Enum _type
|
|
, const bx::StringView& _title
|
|
, const bx::StringView& _filter
|
|
)
|
|
{
|
|
NSMutableArray* fileTypes = [NSMutableArray arrayWithCapacity:10];
|
|
bx::Error err;
|
|
|
|
for (bx::LineReader lr(_filter); !lr.isDone() && err.isOk();)
|
|
{
|
|
const bx::StringView line = lr.next();
|
|
const bx::StringView sep = bx::strFind(line, '|');
|
|
|
|
if (!sep.isEmpty() )
|
|
{
|
|
for (Split split(bx::strTrim(bx::StringView(sep.getPtr()+1, line.getTerm() ), " "), ' '); !split.isDone() && err.isOk();)
|
|
{
|
|
const bx::StringView token = split.next();
|
|
|
|
if ( token.getLength() >= 3 && token.getPtr()[0] == '*'
|
|
&& token.getPtr()[1] == '.' && bx::isAlphaNum(token.getPtr()[2]) )
|
|
{
|
|
NSString* extension = [[NSString alloc] initWithBytes:token.getPtr()+2 length:token.getLength()-2 encoding:NSASCIIStringEncoding];
|
|
[fileTypes addObject: extension];
|
|
}
|
|
}
|
|
}
|
|
}
|
|
|
|
__block NSString* fileName = nil;
|
|
bx::Semaphore semaphore;
|
|
bx::Semaphore* psemaphore = &semaphore;
|
|
|
|
CFRunLoopPerformBlock([[NSRunLoop mainRunLoop] getCFRunLoop],
|
|
kCFRunLoopCommonModes,
|
|
^{
|
|
NSSavePanel* panel = nil;
|
|
|
|
if ( FileSelectionDialogType::Open == _type)
|
|
{
|
|
NSOpenPanel* openPanel = [NSOpenPanel openPanel];
|
|
openPanel.canChooseFiles = TRUE;
|
|
openPanel.allowsMultipleSelection = FALSE;
|
|
openPanel.canChooseDirectories = FALSE;
|
|
panel = openPanel;
|
|
}
|
|
else
|
|
{
|
|
panel = [NSSavePanel savePanel];
|
|
}
|
|
|
|
panel.message = [[NSString alloc] initWithBytes:_title.getPtr() length:_title.getLength() encoding:NSASCIIStringEncoding];
|
|
panel.directoryURL = [NSURL URLWithString:@(_inOutFilePath.getCPtr())];
|
|
panel.allowedFileTypes = fileTypes;
|
|
|
|
if ([panel runModal] == NSModalResponseOK)
|
|
{
|
|
NSURL* url = [panel URL];
|
|
if (nil != url)
|
|
{
|
|
fileName = [url path];
|
|
[fileName retain];
|
|
}
|
|
}
|
|
[panel close];
|
|
psemaphore->post();
|
|
});
|
|
|
|
semaphore.wait();
|
|
|
|
if ( fileName != nil )
|
|
{
|
|
_inOutFilePath.set([fileName UTF8String]);
|
|
[fileName release];
|
|
return true;
|
|
}
|
|
|
|
return false;
|
|
}
|
|
|
|
#endif
|