;////////////////////////////////////////////////////////////////////////
;
;  Вызов окна настройки интерфейса (Options->Interface settings)
;
;////////////////////////////////////////////////////////////////////////
set_interface:
	; настроить массив ячеек CheckBox-а
	call	prep_interface_ceils
	; вывод окна
	ld	hl,win_dial_interface	; описатель окна
	call	DialogW
	cp	evCommand		; событие "команда"
	ret	nz
	ld	a,(hl)			;+1 what
	cp	cmOkey			; "Yes"
	ret	nz
	; Применить настройки
	call	test_show_panels	; тест на режим вкл. панелей
	ret	z
	; сохранить настройки
	call	save_interface_settings
	; обновить панели согласно настройкам
	call	fresh_show_summary_line	; Show line summary information
	call	change_panel		; сменить панель
	call	A20FC			; обновить панель
	call	change_panel
	call	A20FC
	jp	show_pointer		; показать указатель


; Подготовка массива ячеек CheckBox-а
prep_interface_ceils:
	ld	a,(hilight_enable)	; раскраска файлов
	ld	hl,interface_ceil0	; начало массива ячеек
	ld	(hl),a
	inc	hl
	ld	a,(hidden_mouse)	; прятать мышку при работе с клавой
	ld	(hl),a
	inc	hl
	ld	a,(enable_clock)	; вывод часов в панелях
	ld	(hl),a
	inc	hl
	ld	a,(mark_folders)	; отметка папок
	ld	(hl),a
	inc	hl
	ld	a,(flag_summary_info)	; вывод строки суммарной информации
	ld	(hl),a
	inc	hl
	ld	a,(sort_char_flag)	; вывод буквы режима сортировки
	ld	(hl),a
	inc	hl
	ld	a,(enable_down_mark)	; смещ. курсора вниз при выдел. файлов
	ld	(hl),a
	inc	hl
	ld	a,(flag_esc)		; врем. просмотр сист. экрана
	ld	(hl),a
	inc	hl
	ld	a,(move_home_end)	; отработка Home/End в ком-строке при откр. панелях
	ld	(hl),a
	ret


; Сохранить настройки окна "Interface settings"
save_interface_settings:
	ld	hl,interface_ceil0	; начало массива ячеек
	ld	a,(hl)
	ld	(hilight_enable),a	; раскраска файлов
	inc	hl
	ld	a,(hl)
	ld	(hidden_mouse),a	; прятать мышку при работе с клавой
	inc	hl
	ld	a,(hl)
	ld	(enable_clock),a	; вывод часов в панелях
	inc	hl
	ld	a,(hl)
	ld	(mark_folders),a	; отметка папок
	inc	hl
	ld	a,(hl)
	ld	(flag_summary_info),a	; вывод строки суммарной информации
	inc	hl
	ld	a,(hl)
	ld	(sort_char_flag),a	; вывод буквы режима сортировки
	inc	hl
	ld	a,(hl)
	ld	(enable_down_mark),a	; смещ. курсора вниз при выдел. файлов
	inc	hl
	ld	a,(hl)
	ld	(flag_esc),a		; врем. просмотр сист. экрана
	inc	hl
	ld	a,(hl)
	ld	(move_home_end),a	; отработка Home/End в ком-строке
	ret



;-------------------------------------------------
; Настройка вывода строки суммарной инфы
;-------------------------------------------------
fresh_show_summary_line:
	call	test_show_panels	; тест на режим вкл. панелей
	ret	z			; выкл.
	ld	a,(flag_summary_info)	; флаг
	or	a
	ret	z			; false
	jp	get_total_free_space	; узнать своб. место на дисках панелей